Update Gradle wrapper to 8.13 and bump vulnerable dependencies

README.md

@@ -41,7 +41,7 @@ Maven:
 
 Gradle:
 ```
-testCompile group: 'io.appium', name: 'mitmproxy-java', version: '2.0.2'
+testImplementation group: 'io.appium', name: 'mitmproxy-java', version: '2.0.2'
 ```
 
 ## Usage
@@ -89,5 +89,5 @@ See [node-mitmproxy](https://github.com/jvilk/mitmproxy-node/blob/master/README.
 
 ## Develop
 
-Upload to Central Repository with command `./gradlew uploadArchives`
+Upload to Central Repository with command `./gradlew publish`
 Set username and password in `build.gradle` file

build.gradle

@@ -1,104 +1,100 @@
 plugins {
     id 'java-library'
     id 'signing'
-    id 'maven'
+    id 'maven-publish'
 }
 
 group = 'io.appium'
 version = '2.0.2'
-archivesBaseName = 'mitmproxy-java'
 
-sourceCompatibility = 1.8
+base {
+    archivesName = 'mitmproxy-java'
+}
+
+java {
+    sourceCompatibility = JavaVersion.VERSION_1_8
+    targetCompatibility = JavaVersion.VERSION_1_8
+    withJavadocJar()
+    withSourcesJar()
+}
 
 repositories {
     mavenCentral()
 }
 
 dependencies {
-    implementation 'org.java-websocket:Java-WebSocket:1.4.0'
+    implementation 'org.java-websocket:Java-WebSocket:1.5.7'
     implementation group: 'javax.ws.rs', name: 'javax.ws.rs-api', version: '2.0-m02'
     implementation group: 'com.fasterxml.jackson.core', name: 'jackson-core', version: '2.9.8'
     implementation group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.9.8'
     implementation group: 'org.zeroturnaround', name: 'zt-exec', version: '1.10'
     implementation group: 'org.zeroturnaround', name: 'zt-process-killer', version: '1.9'
     implementation group: 'org.slf4j', name: 'slf4j-simple', version: '1.7.26'
-    testCompile group: 'junit', name: 'junit', version: '4.12'
-    testCompile group: 'org.mockito', name: 'mockito-all', version: '1.10.19'
-    testCompile group: 'com.mashape.unirest', name: 'unirest-java', version: '1.4.9'
-    testCompile group: 'org.assertj', name: 'assertj-core', version: '3.12.2'
+    testImplementation group: 'junit', name: 'junit', version: '4.12'
+    testImplementation group: 'org.mockito', name: 'mockito-all', version: '1.10.19'
+    testImplementation group: 'com.mashape.unirest', name: 'unirest-java', version: '1.4.9'
+    testImplementation group: 'org.assertj', name: 'assertj-core', version: '3.12.2'
 
-    compileOnly 'org.projectlombok:lombok:1.18.8'
-    annotationProcessor 'org.projectlombok:lombok:1.18.8'
+    compileOnly 'org.projectlombok:lombok:1.18.36'
+    annotationProcessor 'org.projectlombok:lombok:1.18.36'
 
-    compile group: 'org.apache.commons', name: 'commons-collections4', version: '4.0'
-}
-
-task javadocJar(type: Jar) {
-    classifier = 'javadoc'
-    from javadoc
-}
-task sourcesJar(type: Jar) {
-    classifier = 'sources'
-    from sourceSets.main.allSource
-}
-artifacts {
-    archives javadocJar, sourcesJar
-}
-signing {
-    setRequired {
-        // condition for when signing is required
-        gradle.taskGraph.hasTask("uploadArchives")
-    }
-    sign configurations.archives
+    implementation group: 'org.apache.commons', name: 'commons-collections4', version: '4.4'
 }
 
+publishing {
+    publications {
+        mavenJava(MavenPublication) {
+            from components.java
 
-// Build, sign, and upload
-uploadArchives {
-    repositories {
-        mavenDeployer {
-
-            // Sign POM
-            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
-
-            // Destination
-            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
-                authentication(userName: 'username', password: 'password')
-            }
-            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
-                authentication(userName: 'username', password: 'password')
-            }
-
-            // Add required metadata to POM
-            pom.project {
-                name 'mitmproxy-java'
-                packaging 'jar'
-                description 'A bridge between Python\'s mitmproxy and Java programs. Built on top of mitmproxy-node'
-                url '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/appium/mitmproxy-java'
+            pom {
+                name = 'mitmproxy-java'
+                packaging = 'jar'
+                description = 'A bridge between Python\'s mitmproxy and Java programs. Built on top of mitmproxy-node'
+                url = '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/appium/mitmproxy-java'
 
                 scm {
-                    connection 'scm:git:git://github.com/appium/mitmproxy-java.git'
-                    developerConnection 'scm:git:ssh://github.com/appium/mitmproxy-java.git'
-                    url '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/appium/mitmproxy-java/tree/master'
+                    connection = 'scm:git:git://github.com/appium/mitmproxy-java.git'
+                    developerConnection = 'scm:git:ssh://github.com/appium/mitmproxy-java.git'
+                    url = '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/appium/mitmproxy-java/tree/master'
                 }
 
                 licenses {
                     license {
-                        name 'The Apache License, Version 2.0'
-                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
+                        name = 'The Apache License, Version 2.0'
+                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                     }
                 }
 
                 developers {
                     developer {
-                        id 'jonahss'
-                        name 'Jonah Stiennon'
-                        email 'jonah@cloudgrey.io'
-                        organization 'Cloud Grey'
-                        organizationUrl 'https://cloudgrey.io'
+                        id = 'jonahss'
+                        name = 'Jonah Stiennon'
+                        email = 'jonah@cloudgrey.io'
+                        organization = 'Cloud Grey'
+                        organizationUrl = 'https://cloudgrey.io'
                     }
                 }
             }
         }
     }
+
+    repositories {
+        maven {
+            def releasesRepoUrl = 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
+            def snapshotsRepoUrl = 'https://oss.sonatype.org/content/repositories/snapshots/'
+            url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
+            credentials {
+                username = 'username'
+                password = 'password'
+            }
+        }
+    }
+}
+
+signing {
+    required = {
+        // condition for when signing is required
+        gradle.taskGraph.hasTask("publish")
+    }
+    sign publishing.publications.mavenJava
 }

gradle/wrapper/gradle-wrapper.properties

@@ -1,6 +1,7 @@
-#Thu Apr 11 14:32:28 PDT 2019
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
+distributionUrl=https\://services.gradle.org/distributions/gradle-8.13-all.zip
+networkTimeout=10000
+validateDistributionUrl=true
 zipStoreBase=GRADLE_USER_HOME
 zipStorePath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-4.10-all.zip